VBA × Selenium × OutlookでPDFを自動取得＆メール送信する方法

Sub GetPDF_nsjournal()
    On Error GoTo ErrHandler

    Dim driver As New Selenium.ChromeDriver
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim user_Mail As String
    Dim user_Pass As String
    Dim pdfDate As String
    Dim savePath As String

    '---初期設定---
    Set wb = Workbooks("Demo.xlsm")
    Set ws = wb.Sheets("Sheet1")
    user_Mail = ws.Cells(1, 1).Value
    user_Pass = ws.Cells(2, 1).Value
    pdfDate = Format(Date, "m月d日")
    savePath = Environ("USERPROFILE") & "\Downloads\PDF" & Format(Date, "yyyymmdd") & ".pdf"

    '---ログイン情報チェック---
    If user_Mail = "" Or user_Pass = "" Then
        MsgBox "ログイン情報が未入力です", vbExclamation
        Exit Sub
    End If

    '---ブラウザ起動---
    driver.AddArgument "--start-maximized"
    driver.Start "Chrome"
    driver.Get "https://www.nsjournal.jp/membership-login/"

    '---ログイン処理---
    driver.FindElementByName("swpm_user_name").SendKeys user_Mail
    driver.FindElementByName("swpm_password").SendKeys user_Pass
    driver.FindElementByName("swpm-login").Click
    driver.Wait 5000    '5秒待機

    '---PDFページへ遷移---
    On Error Resume Next
    driver.FindElementByXPath("/html/body/div[1]/header/nav/div[1]/ul/li[11]/a").Click
    If Err.Number <> 0 Then MsgBox "PDFページへの遷移に失敗しました": Exit Sub
    On Error GoTo ErrHandler

    '---当日リンクを探す---
    If driver.FindElementsByPartialLinkText(pdfDate).Count = 0 Then
        MsgBox "本日分のPDFリンクが見つかりません", vbExclamation
        Exit Sub
    End If
    driver.FindElementByPartialLinkText(pdfDate).Click
    driver.Wait 3000    '3秒待機

    '---PDFリンクをクリック---
    driver.FindElementByXPath("//p[@class='files']/a").Click
    Application.Wait Now + TimeValue("0:00:02")

    '---PDF保存（SendKeys）---
    AppActivate "Chrome"
    SendKeys "^s", True
    Application.Wait Now + TimeValue("0:00:02")
    SendKeys "{ENTER}", True

    '---保存完了待機---
    Dim waitTime As Double
    waitTime = Timer + 5
    Do While Timer < waitTime
        DoEvents
    Loop

    '---保存確認---
    If Dir(savePath) = "" Then
        MsgBox "PDFの保存に失敗しました", vbCritical
        Exit Sub
    End If

'    MsgBox "PDF保存完了：" & savePath, vbInformation
    Exit Sub

ErrHandler:
    MsgBox "エラー発生：" & Err.Description, vbCritical
End Sub

Sub Send_nsjournal()
    On Error GoTo ErrHandler

    Dim wb As Workbook
    Dim ws As Worksheet
    Dim user_Mail As String
    Dim toaddress As String
    Dim subject As String
    Dim attached As String
    Dim outlookObj As Outlook.Application
    Dim mailItemObj As Outlook.MailItem
    Dim myattachments As Outlook.Attachments

    '---初期設定---
    Set wb = Workbooks("Demo.xlsm")
    Set ws = wb.Sheets("Sheet1")
    user_Mail = ws.Cells(1, 1).Value
    toaddress = user_Mail
    subject = "日本証券新聞_" & Format(Date, "yyyymmdd")
    attached = Environ("USERPROFILE") & "\Downloads\PDF" & Format(Date, "yyyymmdd") & ".pdf"

    '---メールアドレス確認---
    If toaddress = "" Then
        MsgBox "送信先メールアドレスが未入力です", vbExclamation
        Exit Sub
    End If

    '---添付ファイル確認---
    If Dir(attached) = "" Then
        MsgBox "添付ファイルが見つかりません：" & attached, vbExclamation
        Exit Sub
    End If

    '---Outlook起動とメール作成---
    Set outlookObj = CreateObject("Outlook.Application")
    Set mailItemObj = outlookObj.CreateItem(olMailItem)
    mailItemObj.To = toaddress
    mailItemObj.subject = subject

    '---添付ファイル追加---
    Set myattachments = mailItemObj.Attachments
    myattachments.Add attached

    '---メール表示（手動送信）---
    mailItemObj.Display
'    MsgBox "メールが作成されました。内容を確認して送信してください。", vbInformation
    Exit Sub

ErrHandler:
    MsgBox "メール送信処理中にエラーが発生しました：" & Err.Description, vbCritical
End Sub